scripting/dm_equipment.sp
author Dr!fter
Sat Jun 30 00:38:22 2012 -0400 (2012-06-30)
changeset 81 d46a5ba80277
parent 75 3d3d958970eb
child 92 52cc55d67b2f
permissions -rw-r--r--
Build release
     1 /**
     2  * dm_equipment.sp
     3  * Adds preset spawning to CS:S DM.
     4  * This file is part of CS:S DM, Copyright (C) 2005-2007 AlliedModders LLC
     5  * by David "BAILOPAN" Anderson, http://www.bailopan.net/cssdm/
     6  *
     7  * This program is free software; you can redistribute it and/or
     8  * modify it under the terms of the GNU General Public License
     9  * as published by the Free Software Foundation; either version 2
    10  * of the License, or (at your option) any later version.
    11  *
    12  * This program is distributed in the hope that it will be useful,
    13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
    14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    15  * GNU General Public License for more details.
    16  * 
    17  * You should have received a copy of the GNU General Public License
    18  * along with this program; if not, write to the Free Software
    19  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
    20  *
    21  * Version: $Id$
    22  */
    23 
    24 #pragma semicolon 1
    25 #include <sourcemod>
    26 #include <sdktools>
    27 #include <cssdm>
    28 
    29 #define CSSDM_GUNMENU_NO		0
    30 #define CSSDM_GUNMENU_YES		1
    31 #define CSSDM_GUNMENU_RANDOM	2
    32 
    33 /** Plugin Stuff */
    34 new Handle:cssdm_enable_equipment;					/** cssdm_enable_equipment cvar */
    35 new g_ArmorOffset = -1;								/* m_ArmorValue offset */
    36 new g_NVOffset = -1;								/* m_bHasNightVision offset */
    37 new g_HealthOffset = -1;							/* m_iHealth offset */
    38 new Handle:g_SpawnTimers[MAXPLAYERS+1];				/* Post-spawn timers */
    39 new Handle:g_hPrimaryMenu = INVALID_HANDLE;			/* Priamry menu Handle */
    40 new Handle:g_hSecondaryMenu = INVALID_HANDLE;		/* Secondary menu Handle */
    41 new Handle:g_hEquipMenu = INVALID_HANDLE;			/* Main equipment menu */
    42 new bool:g_IsEnabled = false;						/* Whether the plugin should work */
    43 new g_PrimaryChoices[MAXPLAYERS+1];					/* Primary weapon selections */
    44 new g_SecondaryChoices[MAXPLAYERS+1];				/* Secondary weapon selections */
    45 new bool:g_GunMenuEnabled[MAXPLAYERS+1];			/* Whether the gun menu is enabled */
    46 new bool:g_GunMenuAvailable[MAXPLAYERS+1];			/* Whether the gun menu is available */
    47 
    48 /** HUMAN CONFIGS */
    49 new g_PrimaryList[CSSDM_MAX_WEAPONS];
    50 new g_SecondaryList[CSSDM_MAX_WEAPONS];
    51 new g_PrimaryCount = 0;
    52 new g_SecondaryCount = 0;
    53 new g_PrimaryMenu = CSSDM_GUNMENU_YES;
    54 new g_SecondaryMenu = CSSDM_GUNMENU_YES;
    55 new bool:g_AllowBuy = false;
    56 new g_ArmorAmount = 100;
    57 new bool:g_Helmets = true;
    58 new g_Flashes = 0;
    59 new bool:g_Smokes = false;
    60 new bool:g_HEs = false;
    61 new bool:g_NightVision = false;
    62 new bool:g_DefuseKits = true;
    63 new bool:g_AllowGunCommand = true;
    64 new g_HealthAmount = 100;
    65 
    66 /** BOT CONFIGS */
    67 new g_BotPrimaryList[CSSDM_MAX_WEAPONS];
    68 new g_BotSecondaryList[CSSDM_MAX_WEAPONS];
    69 new g_BotPrimaryCount = 0;
    70 new g_BotSecondaryCount = 0;
    71 new g_BotArmor = 100;
    72 new bool:g_BotHelmets = false;
    73 new g_BotFlashes = 0;
    74 new bool:g_BotSmokes = false;
    75 new bool:g_BotHEs = false;
    76 new bool:g_BotDefuseKits = true;
    77 new g_BotHealthAmount = 100;
    78 
    79 /** PUBLIC INFO */
    80 public Plugin:myinfo = 
    81 {
    82 	name = "CS:S DM Equipment",
    83 	author = "AlliedModders LLC",
    84 	description = "Adds gun menu/equipment to CS:S DM",
    85 	version = CSSDM_VERSION,
    86 	url = "http://www.bailopan.net/cssdm/"
    87 };
    88 
    89 /******************
    90  * IMPLEMENTATION *
    91  ******************/
    92  
    93 public OnPluginStart()
    94 {
    95 	LoadTranslations("cssdm.phrases");
    96 	
    97 	RegConsoleCmd("say", Command_Say);
    98 	RegConsoleCmd("say_team", Command_Say);
    99 	
   100 	cssdm_enable_equipment = CreateConVar("cssdm_enable_equipment", "1", "Sets whether the equipment plugin is enabled");
   101 	HookConVarChange(cssdm_enable_equipment, OnEquipmentEnableChange);
   102 	
   103 	g_ArmorOffset = FindSendPropOffs("CCSPlayer", "m_ArmorValue");
   104 	g_NVOffset = FindSendPropOffs("CCSPlayer", "m_bHasNightVision");
   105 	g_HealthOffset = FindSendPropOffs("CCSPlayer", "m_iHealth");
   106 	
   107 	g_hEquipMenu = CreateMenu(Menu_EquipHandler, MenuAction_DrawItem|MenuAction_DisplayItem);
   108 	SetMenuTitle(g_hEquipMenu, "Weapon Options:");
   109 	SetMenuExitButton(g_hEquipMenu, false);
   110 	AddMenuItem(g_hEquipMenu, "", "New weapons");
   111 	AddMenuItem(g_hEquipMenu, "", "Same weapons");
   112 	AddMenuItem(g_hEquipMenu, "", "Same weapons every time");
   113 	AddMenuItem(g_hEquipMenu, "", "Random weapons");
   114 	AddMenuItem(g_hEquipMenu, "", "Random weapons every time");
   115 }
   116 
   117 public OnEquipmentEnableChange(Handle:convar, const String:oldValue[], const String:newValue[])
   118 {
   119 	g_IsEnabled = StringToInt(newValue) ? true : false;
   120 }
   121 
   122 public OnConfigsExecuted()
   123 {
   124 	LoadDefaults();
   125 	
   126 	if ((g_IsEnabled = LoadConfigFile("cfg/cssdm/cssdm.equip.txt")) == false)
   127 	{
   128 		LogError("[CSSDM] Could not find equipment file \"%s\"", "cfg/cssdm/cssdm.equip.txt");
   129 		return;
   130 	}
   131 	
   132 	if (!GetConVarInt(cssdm_enable_equipment))
   133 	{
   134 		g_IsEnabled = false;
   135 		return;
   136 	}
   137 	
   138 	/** See if there is a map version */
   139 	decl String:map[64];
   140 	decl String:path[255];
   141 	GetCurrentMap(map, sizeof(map));
   142 	Format(path, sizeof(path), "cfg/cssdm/maps/%s.equip.txt", map);
   143 	
   144 	if (FileExists(path))
   145 	{
   146 		LoadConfigFile(path);
   147 	}
   148 }
   149 
   150 public Action:DM_OnClientDeath(client)
   151 {
   152 	if (g_SpawnTimers[client] != INVALID_HANDLE)
   153 	{
   154 		KillTimer(g_SpawnTimers[client]);
   155 		g_SpawnTimers[client] = INVALID_HANDLE;
   156 	}
   157 	g_GunMenuAvailable[client] = true;
   158 }
   159 
   160 public OnClientPutInServer(client)
   161 {
   162 	g_GunMenuEnabled[client] = true;
   163 	g_GunMenuAvailable[client] = true;
   164 	g_PrimaryChoices[client] = -1;
   165 	g_SecondaryChoices[client] = -1;
   166 }
   167 
   168 public OnClientDisconnect(client)
   169 {
   170 	if (g_SpawnTimers[client] != INVALID_HANDLE)
   171 	{
   172 		KillTimer(g_SpawnTimers[client]);
   173 		g_SpawnTimers[client] = INVALID_HANDLE;
   174 	}
   175 }
   176 
   177 public DM_OnClientSpawned(client)
   178 {
   179 	if (!ShouldRun())
   180 	{
   181 		return;
   182 	}
   183 	
   184 	if (!IsFakeClient(client))
   185 	{
   186 		if (g_ArmorAmount > 0)
   187 		{
   188 			GivePlayerItem(client, "item_assaultsuit");
   189 			GivePlayerItem(client, "item_assaultsuit");
   190 			SetClientArmor(client, g_ArmorAmount);
   191 		}
   192 		if (g_HealthAmount > 0)
   193 		{
   194 			SetClientHealth(client, g_HealthAmount);
   195 		}
   196 		if (g_Helmets)
   197 		{
   198 			GivePlayerItem(client, "item_kevlar");
   199 			GivePlayerItem(client, "item_kevlar");
   200 		}
   201 		GiveGrenades(client, g_Flashes, g_HEs, g_Smokes);
   202 		if (g_NightVision)
   203 		{
   204 			GiveNightVision(client);
   205 		}
   206 	}
   207 	else
   208 	{
   209 		/* See if we'll need to strip this bot */
   210 		if (g_BotSecondaryCount || g_BotPrimaryCount)
   211 		{
   212 			DM_StripBotItems(client);
   213 		}
   214 		if (g_BotArmor > 0)
   215 		{
   216 			GivePlayerItem(client, "item_assaultsuit");
   217 			GivePlayerItem(client, "item_assaultsuit");
   218 			SetClientArmor(client, g_BotArmor);
   219 		} else {
   220 			/* Make sure bot didn't buy armor */
   221 			SetClientArmor(client, 0);
   222 		}
   223 		if (g_BotHealthAmount > 0)
   224 		{
   225 			SetClientHealth(client, g_BotHealthAmount);
   226 		}
   227 		if (g_BotHelmets)
   228 		{
   229 			GivePlayerItem(client, "item_kevlar");
   230 			GivePlayerItem(client, "item_kevlar");
   231 		}
   232 		GiveGrenades(client, g_BotFlashes, g_BotHEs, g_BotSmokes);
   233 	}
   234 	if (!g_AllowBuy && g_SpawnTimers[client] == INVALID_HANDLE)
   235 	{
   236 		/* Small delay - we want to avoid ResetHUD */
   237 		g_SpawnTimers[client] = CreateTimer(0.1, PlayerPostSpawn, client);
   238 	}
   239 }
   240 
   241 public Action:PlayerPostSpawn(Handle:timer, any:client)
   242 {
   243 	g_SpawnTimers[client] = INVALID_HANDLE;
   244 	
   245 	if (!ShouldRun())
   246 	{
   247 		return Plugin_Stop;
   248 	}
   249 	
   250 	if (IsFakeClient(client))
   251 	{
   252 		if (g_BotSecondaryCount > 0)
   253 		{
   254 			new index;
   255 			if (g_BotSecondaryCount == 1)
   256 			{
   257 				index = g_BotSecondaryList[0];
   258 			} else {
   259 				index = GetRandomInt(0, g_BotSecondaryCount-1);
   260 				index = g_BotSecondaryList[index];
   261 			}
   262 			decl String:classname[64];
   263 			DM_GetWeaponClassname(index, classname, sizeof(classname));
   264 			GivePlayerItem(client, classname);
   265 		}
   266 		if (g_BotPrimaryCount > 0)
   267 		{
   268 			new index;
   269 			if (g_BotPrimaryCount == 1)
   270 			{
   271 				index = g_BotPrimaryList[0];
   272 			} else {
   273 				index = GetRandomInt(0, g_BotPrimaryCount-1);
   274 				index = g_BotPrimaryList[index];
   275 			}
   276 			decl String:classname[64];
   277 			DM_GetWeaponClassname(index, classname, sizeof(classname));
   278 			GivePlayerItem(client, classname);
   279 		}
   280 		if (g_BotDefuseKits && GetClientTeam(client) == CSSDM_TEAM_CT)
   281 		{
   282 			GivePlayerItem(client, "item_defuser");
   283 		}
   284 	} else {
   285 		if (g_DefuseKits && GetClientTeam(client) == CSSDM_TEAM_CT)
   286 		{
   287 			GivePlayerItem(client, "item_defuser");
   288 		}
   289 		
   290 		new numGiven = 0;
   291 		/* First, check if we should only be giving one of something automatically */
   292 		if ((g_SecondaryMenu == CSSDM_GUNMENU_RANDOM || g_SecondaryMenu == CSSDM_GUNMENU_YES)
   293 			&& g_SecondaryCount == 1)
   294 		{
   295 			GiveSecondary(client, 0);
   296 			numGiven++;
   297 		} else if (g_PrimaryMenu == CSSDM_GUNMENU_RANDOM && g_PrimaryCount > 1) {
   298 			GivePrimary(client, g_PrimaryCount);
   299 			numGiven++;
   300 		}
   301 		
   302 		if ((g_PrimaryMenu == CSSDM_GUNMENU_RANDOM || g_PrimaryMenu == CSSDM_GUNMENU_YES)
   303 			&& g_PrimaryCount == 1)
   304 		{
   305 			GivePrimary(client, 0);
   306 			numGiven++;
   307 		} else if (g_SecondaryMenu == CSSDM_GUNMENU_RANDOM && g_SecondaryCount > 1) {
   308 			GiveSecondary(client, g_SecondaryCount);
   309 			numGiven++;
   310 		}
   311 		
   312 		/* If we've already given two weapons, there is no need for a menu. */
   313 		if (numGiven == 2)
   314 		{
   315 			return Plugin_Stop;
   316 		}
   317 		
   318 		if (g_GunMenuEnabled[client])
   319 		{
   320 			DisplayMenu(g_hEquipMenu, client, MENU_TIME_FOREVER);
   321 		} else {
   322 			GiveBothFromChoices(client);
   323 		}
   324 	}
   325 	
   326 	return Plugin_Stop;
   327 }
   328 
   329 public Action:Command_Say(client, args)
   330 {
   331 	if (!ShouldRun())
   332 	{
   333 		return Plugin_Continue;
   334 	}
   335 	
   336 	new String:text[192];
   337 	GetCmdArg(1, text, sizeof(text));
   338 	
   339 	if (strcmp(text, "guns") == 0)
   340 	{
   341 		if (!g_AllowGunCommand)
   342 		{
   343 			PrintToChat(client, "[CSSDM] %t", "GunsMenuDisabled");
   344 			return Plugin_Handled;
   345 		}
   346 		
   347 		if (!ChooseFromSecondary() && !ChooseFromPrimary())
   348 		{
   349 			PrintToChat(client, "[CSSDM] %t", "GunsMenuNotAvailable");
   350 			return Plugin_Handled;
   351 		}
   352 		
   353 		if (g_GunMenuEnabled[client])
   354 		{
   355 			PrintToChat(client, "[CSSDM] %t", "GunsMenuAlreadyEnabled");
   356 			return Plugin_Handled;
   357 		}
   358 		
   359 		g_GunMenuEnabled[client] = true;
   360 		if (!g_GunMenuAvailable[client])
   361 		{
   362 			PrintToChat(client, "[CSSDM] %t", "GunsMenuReactivated");
   363 		} else {
   364 			DisplayMenu(g_hEquipMenu, client, MENU_TIME_FOREVER);
   365 		}
   366 		
   367 		return Plugin_Handled;
   368 	}
   369 	
   370 	return Plugin_Continue;
   371 }
   372 
   373 public Action:OnClientCommand(client, args)
   374 {
   375 	if (!ShouldRun() || g_AllowBuy)
   376 	{
   377 		return Plugin_Continue;
   378 	}
   379 	
   380 	decl String:cmd[32];
   381 	GetCmdArg(0, cmd, sizeof(cmd));
   382 	
   383 	if (StrEqual(cmd, "buy")
   384 		|| StrEqual(cmd, "autobuy")
   385 		|| StrEqual(cmd, "rebuy")
   386 		|| StrEqual(cmd, "buyequip")
   387 		|| StrEqual(cmd, "buymenu"))
   388 	{
   389 		return Plugin_Handled;
   390 	}
   391 	
   392 	return Plugin_Continue;
   393 }
   394 
   395 public Menu_EquipHandler(Handle:menu, MenuAction:action, param1, param2)
   396 {
   397 	if (!ShouldRun())
   398 	{
   399 		return 0;
   400 	}
   401 	
   402 	if (action == MenuAction_DrawItem)
   403 	{
   404 		if (param2 == 1 || param2 == 2)
   405 		{
   406 			if (g_PrimaryChoices[param1] == -1 && g_SecondaryChoices[param1] == -1)
   407 			{
   408 				return ITEMDRAW_DISABLED;
   409 			}
   410 		}
   411 		return ITEMDRAW_DEFAULT;
   412 	}
   413 	else if (action == MenuAction_Select)
   414 	{
   415 		if (param2 == 0)
   416 		{
   417 			if (ChooseFromSecondary())
   418 			{
   419 				DisplayMenu(g_hSecondaryMenu, param1, MENU_TIME_FOREVER);
   420 			} else if (ChooseFromPrimary()) {
   421 				DisplayMenu(g_hPrimaryMenu, param1, MENU_TIME_FOREVER);
   422 			}
   423 		} else if (param2 == 1) {
   424 			GiveBothFromChoices(param1);
   425 		} else if (param2 == 2) {
   426 			GiveBothFromChoices(param1);
   427 			g_GunMenuEnabled[param1] = false;
   428 			PrintToChat(param1, "[CSSDM] %t", "SayGunsNotify");
   429 		} else if (param2 == 3) {
   430 			GivePrimary(param1, g_PrimaryCount);
   431 			GiveSecondary(param1, g_SecondaryCount);
   432 		} else if (param2 == 4) {
   433 			GivePrimary(param1, g_PrimaryCount);
   434 			GiveSecondary(param1, g_SecondaryCount);
   435 			GiveBothFromChoices(param1);
   436 			g_GunMenuEnabled[param1] = false;
   437 			PrintToChat(param1, "[CSSDM] %t", "SayGunsNotify");
   438 		}
   439 		g_GunMenuAvailable[param1] = false;
   440 	}
   441 	else if (action == MenuAction_DisplayItem)
   442 	{
   443 		decl style;
   444 		decl String:info[12], String:lang_phrase[32];
   445 		
   446 		if (!GetMenuItem(menu, param2, info, sizeof(info), style, lang_phrase, sizeof(lang_phrase)))
   447 		{
   448 			return 0;
   449 		}
   450 		
   451 		decl String:t_phrase[64];
   452 		Format(t_phrase, sizeof(t_phrase), "%T", lang_phrase, param1);
   453 		
   454 		return RedrawMenuItem(t_phrase);
   455 	}
   456 	
   457 	return 0;
   458 }
   459 
   460 public Menu_PrimaryHandler(Handle:menu, MenuAction:action, param1, param2)
   461 {
   462 	if (!ShouldRun())
   463 	{
   464 		return 0;
   465 	}
   466 	
   467 	if (action == MenuAction_DrawItem)
   468 	{
   469 		return ITEMDRAW_DEFAULT;
   470 	}
   471 	else if (action == MenuAction_Select)
   472 	{
   473 		GivePrimary(param1, param2);
   474 	}
   475 	else if (action == MenuAction_Display)
   476 	{
   477 		new Handle:hPanel = Handle:param2;
   478 		decl String:title[128];
   479 		
   480 		Format(title, sizeof(title), "%T:", "Primary weapon", param1);
   481 		
   482 		SetPanelTitle(hPanel, title);
   483 	}
   484 	
   485 	return 0;
   486 }
   487 
   488 public Menu_SecondaryHandler(Handle:menu, MenuAction:action, param1, param2)
   489 {
   490 	if (!ShouldRun())
   491 	{
   492 		return 0;
   493 	}
   494 	
   495 	if (action == MenuAction_DrawItem)
   496 	{
   497 		return ITEMDRAW_DEFAULT;
   498 	}
   499 	else if (action == MenuAction_Select)
   500 	{
   501 		GiveSecondary(param1, param2);
   502 		if (ChooseFromPrimary())
   503 		{
   504 			DisplayMenu(g_hPrimaryMenu, param1, MENU_TIME_FOREVER);
   505 		}
   506 	}
   507 	else if (action == MenuAction_Cancel
   508 			 && param2 == MenuCancel_Exit)
   509 	{
   510 		if (ChooseFromPrimary())
   511 		{
   512 			DisplayMenu(g_hPrimaryMenu, param1, MENU_TIME_FOREVER);
   513 		}
   514 	}
   515 	else if (action == MenuAction_Display)
   516 	{
   517 		new Handle:hPanel = Handle:param2;
   518 		decl String:title[128];
   519 		
   520 		Format(title, sizeof(title), "%T:", "Secondary weapon", param1);
   521 		
   522 		SetPanelTitle(hPanel, title);
   523 	}
   524 	
   525 	return 0;
   526 }
   527 
   528 bool:ChooseFromPrimary()
   529 {
   530 	return (g_PrimaryMenu == CSSDM_GUNMENU_YES
   531 			&& g_PrimaryCount > 1);
   532 }
   533 
   534 bool:ChooseFromSecondary()
   535 {
   536 	return (g_SecondaryMenu == CSSDM_GUNMENU_YES
   537 			&& g_SecondaryCount > 1);
   538 }
   539 
   540 GiveWeapon(client, index)
   541 {
   542 	if (!IsPlayerAlive(client))
   543 	{
   544 		return;
   545 	}
   546 
   547 	new DmWeaponType:type = DM_GetWeaponType(index);
   548 	
   549 	new entity = DM_GetClientWeapon(client, type);
   550 	if (entity != -1)
   551 	{
   552 		DM_DropWeapon(client, entity);
   553 	}
   554 	
   555 	new String:cls[64];
   556 	DM_GetWeaponClassname(index, cls, sizeof(cls));
   557 	
   558 	GivePlayerItem(client, cls);
   559 }
   560 
   561 GiveBothFromChoices(client)
   562 {
   563 	if (ChooseFromPrimary())
   564 	{
   565 		GivePrimary(client, g_PrimaryChoices[client]);
   566 	}
   567 	
   568 	if (ChooseFromSecondary())
   569 	{
   570 		GiveSecondary(client, g_SecondaryChoices[client]);
   571 	}
   572 }
   573 
   574 /**
   575  * Gives a primary weapon to a client.
   576  * If the list_index is > the count, we choose one randomly.
   577  * This is a hack so we can append "Random" to the choice list.
   578  */
   579 GivePrimary(client, list_index)
   580 {
   581 	if (list_index < 0)
   582 	{
   583 		return;
   584 	}
   585 	
   586 	new weapon_index;
   587 	if (list_index >= g_PrimaryCount)
   588 	{
   589 		if (g_PrimaryCount > 1)
   590 		{
   591 			weapon_index = GetRandomInt(0, g_PrimaryCount-1);
   592 			weapon_index = g_PrimaryList[weapon_index];
   593 		} else if (g_PrimaryCount == 1) {
   594 			weapon_index = g_PrimaryList[0];
   595 		} else {
   596 			return;
   597 		}
   598 	} else {
   599 		weapon_index = g_PrimaryList[list_index];
   600 	}
   601 	
   602 	g_PrimaryChoices[client] = list_index;
   603 	
   604 	GiveWeapon(client, weapon_index);
   605 }
   606 
   607 /**
   608  * Gives a secondary weapon to a client.
   609  * If the list_index is > the count, we choose one randomly.
   610  * This is a hack so we can append "Random" to the choice list.
   611  */
   612 GiveSecondary(client, list_index)
   613 {
   614 	if (list_index < 0)
   615 	{
   616 		return;
   617 	}
   618 	
   619 	new weapon_index;
   620 	if (list_index >= g_SecondaryCount)
   621 	{
   622 		if (g_SecondaryCount > 1)
   623 		{
   624 			weapon_index = GetRandomInt(0, g_SecondaryCount-1);
   625 			weapon_index = g_SecondaryList[weapon_index];
   626 		} else if (g_SecondaryCount == 1) {
   627 			weapon_index = g_SecondaryList[0];
   628 		} else {
   629 			return;
   630 		}
   631 	} else {
   632 		weapon_index = g_SecondaryList[list_index];
   633 	}
   634 	
   635 	g_SecondaryChoices[client] = list_index;
   636 	
   637 	GiveWeapon(client, weapon_index);
   638 }
   639 
   640 bool:ShouldRun()
   641 {
   642 	return (DM_IsRunning() && g_IsEnabled);
   643 }
   644 
   645 bool:KvGetYesOrNo(Handle:kv, const String:key[], bool:curdefault)
   646 {
   647 	decl String:value[12];
   648 	KvGetString(kv, key, value, sizeof(value), curdefault ? "yes" : "no");
   649 	return (strcmp(value, "yes") == 0);
   650 }
   651 
   652 KvGetGunMenu(Handle:kv, const String:key[], def)
   653 {
   654 	decl String:sdef[12];
   655 	if (def == CSSDM_GUNMENU_YES)
   656 	{
   657 		strcopy(sdef, sizeof(sdef), "yes");
   658 	} else if (def == CSSDM_GUNMENU_RANDOM) {
   659 		strcopy(sdef, sizeof(sdef), "random");
   660 	} else {
   661 		strcopy(sdef, sizeof(sdef), "no");
   662 	}
   663 	
   664 	decl String:value[12];
   665 	KvGetString(kv, key, value, sizeof(value), sdef);
   666 	
   667 	if (strcmp(value, "yes") == 0)
   668 	{
   669 		return CSSDM_GUNMENU_YES;
   670 	} else if (strcmp(value, "random") == 0) {
   671 		return CSSDM_GUNMENU_RANDOM;
   672 	}
   673 	
   674 	return CSSDM_GUNMENU_NO;
   675 }
   676 
   677 LoadDefaults()
   678 {
   679 	g_PrimaryMenu = CSSDM_GUNMENU_YES;
   680 	g_SecondaryMenu = CSSDM_GUNMENU_YES;
   681 	g_AllowBuy = false;
   682 	g_ArmorAmount = 100;
   683 	g_Helmets = true;
   684 	g_Flashes = 0;
   685 	g_Smokes = false;
   686 	g_HEs = false;
   687 	g_NightVision = false;
   688 	g_DefuseKits = true;
   689 	g_HealthAmount = 100;
   690 	g_AllowGunCommand = true;
   691 }
   692 
   693 bool:LoadConfigFile(const String:path[])
   694 {
   695 	new Handle:kv = CreateKeyValues("Equipment");
   696 	if (!FileToKeyValues(kv, path))
   697 	{
   698 		return false;
   699 	}
   700 	
   701 	decl String:value[255];
   702 	
   703 	/* Load settings */
   704 	if (KvJumpToKey(kv, "Settings"))
   705 	{
   706 		g_AllowGunCommand = KvGetYesOrNo(kv, "guns_command", g_AllowGunCommand);
   707 		KvGoBack(kv);
   708 	}
   709 	
   710 	/* Load menu options */
   711 	if (KvJumpToKey(kv, "Menus"))
   712 	{
   713 		g_PrimaryMenu = KvGetGunMenu(kv, "primary", g_PrimaryMenu);
   714 		g_SecondaryMenu = KvGetGunMenu(kv, "secondary", g_SecondaryMenu);
   715 		g_AllowBuy = KvGetYesOrNo(kv, "buy", g_AllowBuy);
   716 		KvGoBack(kv);
   717 	}
   718 	
   719 	/* Load automatic stuff */
   720 	if (KvJumpToKey(kv, "AutoItems"))
   721 	{
   722 		g_ArmorAmount = KvGetNum(kv, "armor", g_ArmorAmount);
   723 		g_Flashes = KvGetNum(kv, "flashbangs", g_Flashes);
   724 		g_Helmets = KvGetYesOrNo(kv, "helmet", g_Helmets);
   725 		g_Smokes = KvGetYesOrNo(kv, "smokegrenade", g_Smokes);
   726 		g_HEs = KvGetYesOrNo(kv, "hegrenade", g_HEs);
   727 		g_NightVision = KvGetYesOrNo(kv, "nightvision", g_NightVision);
   728 		g_DefuseKits = KvGetYesOrNo(kv, "defusekits", g_DefuseKits);
   729 		g_HealthAmount = KvGetNum(kv, "health", g_HealthAmount);
   730 		KvGoBack(kv);
   731 	}
   732 	
   733 	/* Load bot items */
   734 	if (KvJumpToKey(kv, "BotItems"))
   735 	{
   736 		/* Clear out old lists first */
   737 		g_BotPrimaryCount = 0;
   738 		g_BotSecondaryCount = 0;
   739 		
   740 		if (KvGotoFirstSubKey(kv, false))
   741 		{
   742 			do
   743 			{
   744 				KvGetSectionName(kv, value, sizeof(value));
   745 				if (strcmp(value, "weapon") == 0)
   746 				{
   747 					KvGetString(kv, NULL_STRING, value, sizeof(value));
   748 					new index = DM_GetWeaponID(value);
   749 					if (index != -1)
   750 					{
   751 						new DmWeaponType:type = DM_GetWeaponType(index);
   752 						if (type == DmWeapon_Primary && g_BotPrimaryCount < CSSDM_MAX_WEAPONS)
   753 						{
   754 							g_BotPrimaryList[g_BotPrimaryCount++] = index;
   755 						} else if (type == DmWeapon_Secondary && g_BotSecondaryCount < CSSDM_MAX_WEAPONS) {
   756 							g_BotSecondaryList[g_BotSecondaryCount++] = index;
   757 						}
   758 					}					
   759 				} else if (strcmp(value, "armor") == 0) {
   760 					g_BotArmor = KvGetNum(kv, NULL_STRING, 100);
   761 				} else if (strcmp(value, "helmet") == 0) {
   762 					g_BotHelmets = KvGetYesOrNo(kv, NULL_STRING, true);
   763 				} else if (strcmp(value, "flashbangs") == 0) {
   764 					g_BotFlashes = KvGetNum(kv, NULL_STRING);
   765 				} else if (strcmp(value, "smokegrenade") == 0) {
   766 					g_BotSmokes = KvGetYesOrNo(kv, NULL_STRING, false);
   767 				} else if (strcmp(value, "hegrenade") == 0) {
   768 					g_BotHEs = KvGetYesOrNo(kv, NULL_STRING, false);
   769 				} else if (strcmp(value, "defusekits") == 0) {
   770 					g_BotDefuseKits = KvGetYesOrNo(kv, NULL_STRING, true);
   771 				} else if (strcmp(value, "health") == 0) {
   772 					g_BotHealthAmount = KvGetNum(kv, NULL_STRING, 100);
   773 				}
   774 			} while (KvGotoNextKey(kv, false));
   775 			KvGoBack(kv);
   776 		}
   777 		KvGoBack(kv);
   778 	}
   779 	
   780 	/* Load secondary weapons */
   781 	if (KvJumpToKey(kv, "SecondaryMenu"))
   782 	{
   783 		/* Clear out old list first */
   784 		g_SecondaryCount = 0;
   785 		
   786 		if (KvGotoFirstSubKey(kv, false))
   787 		{
   788 			do
   789 			{
   790 				KvGetSectionName(kv, value, sizeof(value));
   791 				if (strcmp(value, "weapon") == 0)
   792 				{
   793 					KvGetString(kv, NULL_STRING, value, sizeof(value));
   794 					new index = DM_GetWeaponID(value);
   795 					if (index != -1 && DM_GetWeaponType(index) == DmWeapon_Secondary)
   796 					{
   797 						g_SecondaryList[g_SecondaryCount++] = index;
   798 					}
   799 				}
   800 			} while (KvGotoNextKey(kv, false) && g_SecondaryCount < CSSDM_MAX_WEAPONS);
   801 			KvGoBack(kv);
   802 		}
   803 		KvGoBack(kv);
   804 	}
   805 	
   806 	/* Load primary weapons */
   807 	if (KvJumpToKey(kv, "PrimaryMenu"))
   808 	{
   809 		/* Clear out old list first */
   810 		g_PrimaryCount = 0;
   811 		
   812 		if (KvGotoFirstSubKey(kv, false))
   813 		{
   814 			do
   815 			{
   816 				KvGetSectionName(kv, value, sizeof(value));
   817 				if (strcmp(value, "weapon") == 0)
   818 				{
   819 					KvGetString(kv, NULL_STRING, value, sizeof(value));
   820 					new index = DM_GetWeaponID(value);
   821 					if (index != -1 && DM_GetWeaponType(index) == DmWeapon_Primary)
   822 					{
   823 						g_PrimaryList[g_PrimaryCount++] = index;
   824 					}
   825 				}
   826 			} while (KvGotoNextKey(kv, false) && g_PrimaryCount < CSSDM_MAX_WEAPONS);
   827 			KvGoBack(kv);
   828 		}
   829 		KvGoBack(kv);
   830 	}
   831 	
   832 	CloseHandle(kv);
   833 	
   834 	/* Build the primary menu */
   835 	if (g_hPrimaryMenu != INVALID_HANDLE)
   836 	{
   837 		CloseHandle(g_hPrimaryMenu);
   838 	}
   839 	g_hPrimaryMenu = CreateMenu(Menu_PrimaryHandler, MenuAction_DrawItem|MenuAction_Display);
   840 	SetMenuTitle(g_hPrimaryMenu, "Primary weapon:");
   841 	for (new i=0; i<g_PrimaryCount; i++)
   842 	{
   843 		new index = g_PrimaryList[i];
   844 		DM_GetWeaponName(index, value, sizeof(value));
   845 		AddMenuItem(g_hPrimaryMenu, "", value);
   846 	}
   847 	AddMenuItem(g_hPrimaryMenu, "", "Random");
   848 	
   849 	/* Build the secondary menu */
   850 	if (g_hSecondaryMenu != INVALID_HANDLE)
   851 	{
   852 		CloseHandle(g_hSecondaryMenu);
   853 	}
   854 	g_hSecondaryMenu = CreateMenu(Menu_SecondaryHandler, MenuAction_DrawItem|MenuAction_Display);
   855 	SetMenuTitle(g_hSecondaryMenu, "Secondary weapon:");
   856 	for (new i=0; i<g_SecondaryCount; i++)
   857 	{
   858 		new index = g_SecondaryList[i];
   859 		DM_GetWeaponName(index, value, sizeof(value));
   860 		AddMenuItem(g_hSecondaryMenu, "", value);
   861 	}
   862 	AddMenuItem(g_hSecondaryMenu, "", "Random");
   863 	
   864 	return true;
   865 }
   866 
   867 SetClientArmor(client, armor)
   868 {
   869 	if (g_ArmorOffset == -1)
   870 	{
   871 		return;
   872 	}
   873 	
   874 	SetEntData(client, g_ArmorOffset, armor, 4, true);
   875 }
   876 
   877 SetClientHealth(client, health)
   878 {
   879 	if (g_HealthOffset == -1)
   880 	{
   881 		return;
   882 	}
   883 	
   884 	SetEntData(client, g_HealthOffset, health, 4, true);
   885 }
   886 
   887 GiveGrenades(client, flashnum, bool:he, bool:smoke)
   888 {
   889 	if (!IsPlayerAlive(client))
   890 	{
   891 		return;
   892 	}
   893 
   894 	if (he)
   895 	{
   896 		GivePlayerItem(client, "weapon_hegrenade");
   897 	}
   898 	for (new i=0; i<flashnum; i++)
   899 	{
   900 		GivePlayerItem(client, "weapon_flashbang");
   901 	}
   902 	if (smoke)
   903 	{
   904 		GivePlayerItem(client, "weapon_smokegrenade");
   905 	}
   906 }
   907 
   908 GiveNightVision(client)
   909 {
   910 	if (g_NVOffset == -1)
   911 	{
   912 		return;
   913 	}
   914 	
   915 	SetEntData(client, g_NVOffset, true, 1, true);
   916 }
   917