Home - sourcemod-central - file revision - plugins/admin-sql-prefetch.sp@47e48ab11bc3 Mercurial
summary | shortlog | changelog | graph | tags | branches | files | changeset | file | latest | revisions | annotate | diff | raw | help
plugins/admin-sql-prefetch.sp
author Nicholas Hastings <skamonkey@gmail.com>
Tue Jun 18 12:16:48 2013 -0400 (2013-06-18)
changeset 3925 47e48ab11bc3
parent 2641 f56dd4215df6
permissions -rw-r--r--
Fixed Dota build. 
     1 /**
     2  * vim: set ts=4 :
     3  * =============================================================================
     4  * SourceMod SQL Admins Plugin (Prefetch)
     5  * Prefetches admins from an SQL database without threading.
     6  *
     7  * SourceMod (C)2004-2008 AlliedModders LLC.  All rights reserved.
     8  * =============================================================================
     9  *
    10  * This program is free software; you can redistribute it and/or modify it under
    11  * the terms of the GNU General Public License, version 3.0, as published by the
    12  * Free Software Foundation.
    13  * 
    14  * This program is distributed in the hope that it will be useful, but WITHOUT
    15  * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
    16  * FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
    17  * details.
    18  *
    19  * You should have received a copy of the GNU General Public License along with
    20  * this program.  If not, see <http://www.gnu.org/licenses/>.
    21  *
    22  * As a special exception, AlliedModders LLC gives you permission to link the
    23  * code of this program (as well as its derivative works) to "Half-Life 2," the
    24  * "Source Engine," the "SourcePawn JIT," and any Game MODs that run on software
    25  * by the Valve Corporation.  You must obey the GNU General Public License in
    26  * all respects for all other code used.  Additionally, AlliedModders LLC grants
    27  * this exception to all derivative works.  AlliedModders LLC defines further
    28  * exceptions, found in LICENSE.txt (as of this writing, version JULY-31-2007),
    29  * or <http://www.sourcemod.net/license.php>.
    30  *
    31  * Version: $Id$
    32  */
    33 
    34 /* We like semicolons */
    35 #pragma semicolon 1
    36 
    37 #include <sourcemod>
    38 
    39 public Plugin:myinfo = 
    40 {
    41 	name = "SQL Admins (Prefetch)",
    42 	author = "AlliedModders LLC",
    43 	description = "Reads all admins from SQL",
    44 	version = SOURCEMOD_VERSION,
    45 	url = "http://www.sourcemod.net/"
    46 };
    47 
    48 public OnRebuildAdminCache(AdminCachePart:part)
    49 {
    50 	/* First try to get a database connection */
    51 	decl String:error[255];
    52 	new Handle:db;
    53 	
    54 	if (SQL_CheckConfig("admins"))
    55 	{
    56 		db = SQL_Connect("admins", true, error, sizeof(error));
    57 	} else {
    58 		db = SQL_Connect("default", true, error, sizeof(error));
    59 	}
    60 	
    61 	if (db == INVALID_HANDLE)
    62 	{
    63 		LogError("Could not connect to database \"default\": %s", error);
    64 		return;
    65 	}
    66 	
    67 	if (part == AdminCache_Overrides)
    68 	{
    69 		FetchOverrides(db);
    70 	} else if (part == AdminCache_Groups) {
    71 		FetchGroups(db);
    72 	} else if (part == AdminCache_Admins) {
    73 		FetchUsers(db);
    74 	}
    75 	
    76 	CloseHandle(db);
    77 }
    78 
    79 FetchUsers(Handle:db)
    80 {
    81 	decl String:query[255], String:error[255];
    82 	new Handle:hQuery;
    83 
    84 	Format(query, sizeof(query), "SELECT id, authtype, identity, password, flags, name, immunity FROM sm_admins");
    85 	if ((hQuery = SQL_Query(db, query)) == INVALID_HANDLE)
    86 	{
    87 		SQL_GetError(db, error, sizeof(error));
    88 		LogError("FetchUsers() query failed: %s", query);
    89 		LogError("Query error: %s", error);
    90 		return;
    91 	}
    92 
    93 	decl String:authtype[16];
    94 	decl String:identity[80];
    95 	decl String:password[80];
    96 	decl String:flags[32];
    97 	decl String:name[80];
    98 	new immunity;
    99 	new AdminId:adm, id;
   100 	new GroupId:gid;
   101 
   102 	/* Keep track of a mapping from admin DB IDs to internal AdminIds to
   103 	 * enable group lookups en masse */
   104 	new Handle:htAdmins = CreateTrie();
   105 	decl String:key[16];
   106 	
   107 	while (SQL_FetchRow(hQuery))
   108 	{
   109 		id = SQL_FetchInt(hQuery, 0);
   110 		IntToString(id, key, sizeof(key));
   111 		SQL_FetchString(hQuery, 1, authtype, sizeof(authtype));
   112 		SQL_FetchString(hQuery, 2, identity, sizeof(identity));
   113 		SQL_FetchString(hQuery, 3, password, sizeof(password));
   114 		SQL_FetchString(hQuery, 4, flags, sizeof(flags));
   115 		SQL_FetchString(hQuery, 5, name, sizeof(name));
   116 		immunity = SQL_FetchInt(hQuery, 6);
   117 		
   118 		/* Use a pre-existing admin if we can */
   119 		if ((adm = FindAdminByIdentity(authtype, identity)) == INVALID_ADMIN_ID)
   120 		{
   121 			adm = CreateAdmin(name);
   122 			if (!BindAdminIdentity(adm, authtype, identity))
   123 			{
   124 				LogError("Could not bind prefetched SQL admin (authtype \"%s\") (identity \"%s\")", authtype, identity);
   125 				continue;
   126 			}
   127 		}
   128 
   129 		SetTrieValue(htAdmins, key, adm);
   130 		
   131 		#if defined _DEBUG
   132 		PrintToServer("Found SQL admin (%d,%s,%s,%s,%s,%s,%d):%d", id, authtype, identity, password, flags, name, immunity, adm);
   133 		#endif
   134 		
   135 		/* See if this admin wants a password */
   136 		if (password[0] != '\0')
   137 		{
   138 			SetAdminPassword(adm, password);
   139 		}
   140 		
   141 		/* Apply each flag */
   142 		new len = strlen(flags);
   143 		new AdminFlag:flag;
   144 		for (new i=0; i<len; i++)
   145 		{
   146 			if (!FindFlagByChar(flags[i], flag))
   147 			{
   148 				continue;
   149 			}
   150 			SetAdminFlag(adm, flag, true);
   151 		}
   152 
   153 		SetAdminImmunityLevel(adm, immunity);
   154 	}
   155 
   156 	new Handle:hGroupQuery;
   157 	Format(query, sizeof(query), "SELECT ag.admin_id AS id, g.name FROM sm_admins_groups ag JOIN sm_groups g ON ag.group_id = g.id  ORDER BY id, inherit_order ASC");
   158 	if ((hGroupQuery = SQL_Query(db, query)) == INVALID_HANDLE)
   159 	{
   160 		SQL_GetError(db, error, sizeof(error));
   161 		LogError("FetchUsers() query failed: %s", query);
   162 		LogError("Query error: %s", error);
   163 		return;
   164 	}
   165 
   166 	decl String:group[80];
   167 	while (SQL_FetchRow(hGroupQuery))
   168 	{
   169 		IntToString(SQL_FetchInt(hGroupQuery, 0), key, sizeof(key));
   170 		SQL_FetchString(hGroupQuery, 1, group, sizeof(group));
   171 
   172 		if (GetTrieValue(htAdmins, key, adm))
   173 		{
   174 			if ((gid = FindAdmGroup(group)) == INVALID_GROUP_ID)
   175 			{
   176 				/* Group wasn't found, don't bother with it.  */
   177 				continue;
   178 			}
   179 
   180 			AdminInheritGroup(adm, gid);
   181 		}
   182 	}
   183 	
   184 	CloseHandle(hQuery);
   185 	CloseHandle(hGroupQuery);
   186 	CloseHandle(htAdmins);
   187 }
   188 
   189 FetchGroups(Handle:db)
   190 {
   191 	decl String:query[255];
   192 	new Handle:hQuery;
   193 	
   194 	Format(query, sizeof(query), "SELECT flags, name, immunity_level FROM sm_groups");
   195 
   196 	if ((hQuery = SQL_Query(db, query)) == INVALID_HANDLE)
   197 	{
   198 		decl String:error[255];
   199 		SQL_GetError(db, error, sizeof(error));
   200 		LogError("FetchGroups() query failed: %s", query);
   201 		LogError("Query error: %s", error);
   202 		return;
   203 	}
   204 	
   205 	/* Now start fetching groups */
   206 	decl String:flags[32];
   207 	decl String:name[128];
   208 	new immunity;
   209 	while (SQL_FetchRow(hQuery))
   210 	{
   211 		SQL_FetchString(hQuery, 0, flags, sizeof(flags));
   212 		SQL_FetchString(hQuery, 1, name, sizeof(name));
   213 		immunity = SQL_FetchInt(hQuery, 2);
   214 		
   215 #if defined _DEBUG
   216 		PrintToServer("Adding group (%d, %s, %s)", immunity, flags, name);
   217 #endif
   218 		
   219 		/* Find or create the group */
   220 		new GroupId:gid;
   221 		if ((gid = FindAdmGroup(name)) == INVALID_GROUP_ID)
   222 		{
   223 			gid = CreateAdmGroup(name);
   224 		}
   225 		
   226 		/* Add flags from the database to the group */
   227 		new num_flag_chars = strlen(flags);
   228 		for (new i=0; i<num_flag_chars; i++)
   229 		{
   230 			decl AdminFlag:flag;
   231 			if (!FindFlagByChar(flags[i], flag))
   232 			{
   233 				continue;
   234 			}
   235 			SetAdmGroupAddFlag(gid, flag, true);
   236 		}
   237 		
   238 		/* Set the immunity level this group has */
   239 		SetAdmGroupImmunityLevel(gid, immunity);
   240 	}
   241 	
   242 	CloseHandle(hQuery);
   243 	
   244 	/** 
   245 	 * Get immunity in a big lump.  This is a nasty query but it gets the job done.
   246 	 */
   247 	new len = 0;
   248 	len += Format(query[len], sizeof(query)-len, "SELECT g1.name, g2.name FROM sm_group_immunity gi");
   249 	len += Format(query[len], sizeof(query)-len, " LEFT JOIN sm_groups g1 ON g1.id = gi.group_id ");
   250 	len += Format(query[len], sizeof(query)-len, " LEFT JOIN sm_groups g2 ON g2.id = gi.other_id");
   251 	
   252 	if ((hQuery = SQL_Query(db, query)) == INVALID_HANDLE)
   253 	{
   254 		decl String:error[255];
   255 		SQL_GetError(db, error, sizeof(error));
   256 		LogError("FetchGroups() query failed: %s", query);
   257 		LogError("Query error: %s", error);
   258 		return;
   259 	}
   260 	
   261 	while (SQL_FetchRow(hQuery))
   262 	{
   263 		decl String:group1[80];
   264 		decl String:group2[80];
   265 		new GroupId:gid1, GroupId:gid2;
   266 		
   267 		SQL_FetchString(hQuery, 0, group1, sizeof(group1));
   268 		SQL_FetchString(hQuery, 1, group2, sizeof(group2));
   269 		
   270 		if (((gid1 = FindAdmGroup(group1)) == INVALID_GROUP_ID)
   271 			|| (gid2 = FindAdmGroup(group2)) == INVALID_GROUP_ID)
   272 		{
   273 			continue;
   274 		}
   275 		
   276 		SetAdmGroupImmuneFrom(gid1, gid2);
   277 #if defined _DEBUG
   278 		PrintToServer("SetAdmGroupImmuneFrom(%d, %d)", gid1, gid2);
   279 #endif
   280 	}
   281 	
   282 	CloseHandle(hQuery);
   283 	
   284 	/**
   285 	 * Fetch overrides in a lump query.
   286 	 */
   287 	Format(query, sizeof(query), "SELECT g.name, go.type, go.name, go.access FROM sm_group_overrides go LEFT JOIN sm_groups g ON go.group_id = g.id");
   288 	
   289 	if ((hQuery = SQL_Query(db, query)) == INVALID_HANDLE)
   290 	{
   291 		decl String:error[255];
   292 		SQL_GetError(db, error, sizeof(error));
   293 		LogError("FetchGroups() query failed: %s", query);
   294 		LogError("Query error: %s", error);
   295 		return;
   296 	}
   297 	
   298 	decl String:type[16];
   299 	decl String:cmd[64];
   300 	decl String:access[16];
   301 	while (SQL_FetchRow(hQuery))
   302 	{
   303 		SQL_FetchString(hQuery, 0, name, sizeof(name));
   304 		SQL_FetchString(hQuery, 1, type, sizeof(type));
   305 		SQL_FetchString(hQuery, 2, cmd, sizeof(cmd));
   306 		SQL_FetchString(hQuery, 3, access, sizeof(access));
   307 		
   308 		new GroupId:gid;
   309 		if ((gid = FindAdmGroup(name)) == INVALID_GROUP_ID)
   310 		{
   311 			continue;
   312 		}
   313 				
   314 		new OverrideType:o_type = Override_Command;
   315 		if (StrEqual(type, "group"))
   316 		{
   317 			o_type = Override_CommandGroup;
   318 		}
   319 		
   320 		new OverrideRule:o_rule = Command_Deny;
   321 		if (StrEqual(access, "allow"))
   322 		{
   323 			o_rule = Command_Allow;
   324 		}
   325 				
   326 		#if defined _DEBUG
   327 		PrintToServer("AddAdmGroupCmdOverride(%d, %s, %d, %d)", gid, cmd, o_type, o_rule);
   328 		#endif
   329 		
   330 		AddAdmGroupCmdOverride(gid, cmd, o_type, o_rule);
   331 	}
   332 	
   333 	CloseHandle(hQuery);
   334 }
   335 
   336 FetchOverrides(Handle:db)
   337 {
   338 	decl String:query[255];
   339 	new Handle:hQuery;
   340 	
   341 	Format(query, sizeof(query), "SELECT type, name, flags FROM sm_overrides");
   342 
   343 	if ((hQuery = SQL_Query(db, query)) == INVALID_HANDLE)
   344 	{
   345 		decl String:error[255];
   346 		SQL_GetError(db, error, sizeof(error));
   347 		LogError("FetchOverrides() query failed: %s", query);
   348 		LogError("Query error: %s", error);
   349 		return;
   350 	}
   351 	
   352 	decl String:type[64];
   353 	decl String:name[64];
   354 	decl String:flags[32];
   355 	new flag_bits;
   356 	while (SQL_FetchRow(hQuery))
   357 	{
   358 		SQL_FetchString(hQuery, 0, type, sizeof(type));
   359 		SQL_FetchString(hQuery, 1, name, sizeof(name));
   360 		SQL_FetchString(hQuery, 2, flags, sizeof(flags));
   361 		
   362 #if defined _DEBUG
   363 		PrintToServer("Adding override (%s, %s, %s)", type, name, flags);
   364 #endif
   365 		
   366 		flag_bits = ReadFlagString(flags);
   367 		if (StrEqual(type, "command"))
   368 		{
   369 			AddCommandOverride(name, Override_Command, flag_bits);
   370 		} else if (StrEqual(type, "group")) {
   371 			AddCommandOverride(name, Override_CommandGroup, flag_bits);
   372 		}
   373 	}
   374 	
   375 	CloseHandle(hQuery);
   376 }
   377
sourcemod-central
Feed