Home - sourcemod-central - file revision - plugins/reservedslots.sp@fcf4e97e0844 Mercurial
summary | shortlog | changelog | graph | tags | branches | files | changeset | file | latest | revisions | annotate | diff | raw | help
plugins/reservedslots.sp
author Nicholas Hastings <skamonkey@gmail.com>
Tue Oct 11 19:41:56 2011 -0400 (2011-10-11)
changeset 3398 fcf4e97e0844
parent 2920 1d5645ab7ae0
child 3419 b1010658bf7f
permissions -rw-r--r--
Fixed wrong values for unsigned, >= 16-bit props in GetEntProp (bug 5105, r=fyren). 
     1 /**
     2  * vim: set ts=4 :
     3  * =============================================================================
     4  * SourceMod Reserved Slots Plugin
     5  * Provides basic reserved slots.
     6  *
     7  * SourceMod (C)2004-2008 AlliedModders LLC.  All rights reserved.
     8  * =============================================================================
     9  *
    10  * This program is free software; you can redistribute it and/or modify it under
    11  * the terms of the GNU General Public License, version 3.0, as published by the
    12  * Free Software Foundation.
    13  * 
    14  * This program is distributed in the hope that it will be useful, but WITHOUT
    15  * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
    16  * FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
    17  * details.
    18  *
    19  * You should have received a copy of the GNU General Public License along with
    20  * this program.  If not, see <http://www.gnu.org/licenses/>.
    21  *
    22  * As a special exception, AlliedModders LLC gives you permission to link the
    23  * code of this program (as well as its derivative works) to "Half-Life 2," the
    24  * "Source Engine," the "SourcePawn JIT," and any Game MODs that run on software
    25  * by the Valve Corporation.  You must obey the GNU General Public License in
    26  * all respects for all other code used.  Additionally, AlliedModders LLC grants
    27  * this exception to all derivative works.  AlliedModders LLC defines further
    28  * exceptions, found in LICENSE.txt (as of this writing, version JULY-31-2007),
    29  * or <http://www.sourcemod.net/license.php>.
    30  *
    31  * Version: $Id$
    32  */
    33 
    34 #pragma semicolon 1
    35 
    36 #include <sourcemod>
    37 
    38 public Plugin:myinfo = 
    39 {
    40 	name = "Reserved Slots",
    41 	author = "AlliedModders LLC",
    42 	description = "Provides basic reserved slots",
    43 	version = SOURCEMOD_VERSION,
    44 	url = "http://www.sourcemod.net/"
    45 };
    46 
    47 new g_adminCount = 0;
    48 new bool:g_isAdmin[MAXPLAYERS+1];
    49 
    50 /* Handles to convars used by plugin */
    51 new Handle:sm_reserved_slots;
    52 new Handle:sm_hide_slots;
    53 new Handle:sv_visiblemaxplayers;
    54 new Handle:sm_reserve_type;
    55 new Handle:sm_reserve_maxadmins;
    56 new Handle:sm_reserve_kicktype;
    57 
    58 enum KickType
    59 {
    60 	Kick_HighestPing,
    61 	Kick_HighestTime,
    62 	Kick_Random,	
    63 };
    64 
    65 public OnPluginStart()
    66 {
    67 	LoadTranslations("reservedslots.phrases");
    68 	
    69 	sm_reserved_slots = CreateConVar("sm_reserved_slots", "0", "Number of reserved player slots", 0, true, 0.0);
    70 	sm_hide_slots = CreateConVar("sm_hide_slots", "0", "If set to 1, reserved slots will hidden (subtracted from the max slot count)", 0, true, 0.0, true, 1.0);
    71 	sv_visiblemaxplayers = FindConVar("sv_visiblemaxplayers");
    72 	sm_reserve_type = CreateConVar("sm_reserve_type", "0", "Method of reserving slots", 0, true, 0.0, true, 2.0);
    73 	sm_reserve_maxadmins = CreateConVar("sm_reserve_maxadmins", "1", "Maximum amount of admins to let in the server with reserve type 2", 0, true, 0.0);
    74 	sm_reserve_kicktype = CreateConVar("sm_reserve_kicktype", "0", "How to select a client to kick (if appropriate)", 0, true, 0.0, true, 2.0);
    75 	
    76 	HookConVarChange(sm_reserved_slots, SlotsChanged);
    77 	HookConVarChange(sm_hide_slots, SlotsChanged);
    78 }
    79 
    80 public OnPluginEnd()
    81 {
    82 	/* 	If the plugin has been unloaded, reset visiblemaxplayers. In the case of the server shutting down this effect will not be visible */
    83 	SetConVarInt(sv_visiblemaxplayers, MaxClients);
    84 }
    85 
    86 public OnMapStart()
    87 {
    88 	if (GetConVarBool(sm_hide_slots))
    89 	{		
    90 		SetVisibleMaxSlots(GetClientCount(false), MaxClients - GetConVarInt(sm_reserved_slots));
    91 	}
    92 }
    93 
    94 public OnConfigsExecuted()
    95 {
    96 	if (GetConVarBool(sm_hide_slots))
    97 	{
    98 		SetVisibleMaxSlots(GetClientCount(false), MaxClients - GetConVarInt(sm_reserved_slots));
    99 	}	
   100 }
   101 
   102 public Action:OnTimedKick(Handle:timer, any:client)
   103 {	
   104 	if (!client || !IsClientInGame(client))
   105 	{
   106 		return Plugin_Handled;
   107 	}
   108 	
   109 	KickClient(client, "%T", "Slot reserved", client);
   110 	
   111 	if (GetConVarBool(sm_hide_slots))
   112 	{				
   113 		SetVisibleMaxSlots(GetClientCount(false), MaxClients - GetConVarInt(sm_reserved_slots));
   114 	}
   115 	
   116 	return Plugin_Handled;
   117 }
   118 
   119 public OnClientPostAdminCheck(client)
   120 {
   121 	new reserved = GetConVarInt(sm_reserved_slots);
   122 
   123 	if (reserved > 0)
   124 	{
   125 		new clients = GetClientCount(false);
   126 		new limit = MaxClients - reserved;
   127 		new flags = GetUserFlagBits(client);
   128 		
   129 		new type = GetConVarInt(sm_reserve_type);
   130 		
   131 		if (type == 0)
   132 		{
   133 			if (clients <= limit || IsFakeClient(client) || flags & ADMFLAG_ROOT || flags & ADMFLAG_RESERVATION)
   134 			{
   135 				if (GetConVarBool(sm_hide_slots))
   136 				{
   137 					SetVisibleMaxSlots(clients, limit);
   138 				}
   139 				
   140 				return;
   141 			}
   142 			
   143 			/* Kick player because there are no public slots left */
   144 			CreateTimer(0.1, OnTimedKick, client);
   145 		}
   146 		else if (type == 1)
   147 		{	
   148 			if (clients > limit)
   149 			{
   150 				if (flags & ADMFLAG_ROOT || flags & ADMFLAG_RESERVATION)
   151 				{
   152 					new target = SelectKickClient();
   153 						
   154 					if (target)
   155 					{
   156 						/* Kick public player to free the reserved slot again */
   157 						CreateTimer(0.1, OnTimedKick, target);
   158 					}
   159 				}
   160 				else
   161 				{				
   162 					/* Kick player because there are no public slots left */
   163 					CreateTimer(0.1, OnTimedKick, client);
   164 				}
   165 			}
   166 		}
   167 		else if (type == 2)
   168 		{
   169 			if (flags & ADMFLAG_ROOT || flags & ADMFLAG_RESERVATION)
   170 			{
   171 				g_adminCount++;
   172 				g_isAdmin[client] = true;
   173 			}
   174 			
   175 			if (clients > limit && g_adminCount < GetConVarInt(sm_reserve_maxadmins))
   176 			{
   177 				/* Server is full, reserved slots aren't and client doesn't have reserved slots access */
   178 				
   179 				if (g_isAdmin[client])
   180 				{
   181 					new target = SelectKickClient();
   182 						
   183 					if (target)
   184 					{
   185 						/* Kick public player to free the reserved slot again */
   186 						CreateTimer(0.1, OnTimedKick, target);
   187 					}
   188 				}
   189 				else
   190 				{				
   191 					/* Kick player because there are no public slots left */
   192 					CreateTimer(0.1, OnTimedKick, client);
   193 				}		
   194 			}
   195 		}
   196 	}
   197 }
   198 
   199 public OnClientDisconnect_Post(client)
   200 {
   201 	if (GetConVarBool(sm_hide_slots))
   202 	{		
   203 		SetVisibleMaxSlots(GetClientCount(false), MaxClients - GetConVarInt(sm_reserved_slots));
   204 	}
   205 	
   206 	if (g_isAdmin[client])
   207 	{
   208 		g_adminCount--;
   209 		g_isAdmin[client] = false;	
   210 	}
   211 }
   212 
   213 public SlotsChanged(Handle:convar, const String:oldValue[], const String:newValue[])
   214 {
   215 	/* Reserved slots or hidden slots have been disabled - reset sv_visiblemaxplayers */
   216 	if (StringToInt(newValue) == 0)
   217 	{
   218 		SetConVarInt(sv_visiblemaxplayers, MaxClients);
   219 	}
   220 }
   221 
   222 SetVisibleMaxSlots(clients, limit)
   223 {
   224 	new num = clients;
   225 	
   226 	if (clients == MaxClients)
   227 	{
   228 		num = MaxClients;
   229 	} else if (clients < limit) {
   230 		num = limit;
   231 	}
   232 	
   233 	SetConVarInt(sv_visiblemaxplayers, num);
   234 }
   235 
   236 SelectKickClient()
   237 {
   238 	new KickType:type = KickType:GetConVarInt(sm_reserve_kicktype);
   239 	
   240 	new Float:highestValue;
   241 	new highestValueId;
   242 	
   243 	new Float:highestSpecValue;
   244 	new highestSpecValueId;
   245 	
   246 	new bool:specFound;
   247 	
   248 	new Float:value;
   249 	
   250 	for (new i=1; i<=MaxClients; i++)
   251 	{	
   252 		if (!IsClientConnected(i))
   253 		{
   254 			continue;
   255 		}
   256 	
   257 		new flags = GetUserFlagBits(i);
   258 		
   259 		if (IsFakeClient(i) || flags & ADMFLAG_ROOT || flags & ADMFLAG_RESERVATION || CheckCommandAccess(i, "sm_reskick_immunity", ADMFLAG_RESERVATION, false))
   260 		{
   261 			continue;
   262 		}
   263 		
   264 		value = 0.0;
   265 			
   266 		if (IsClientInGame(i))
   267 		{
   268 			if (type == Kick_HighestPing)
   269 			{
   270 				value = GetClientAvgLatency(i, NetFlow_Outgoing);
   271 			}
   272 			else if (type == Kick_HighestTime)
   273 			{
   274 				value = GetClientTime(i);
   275 			}
   276 			else
   277 			{
   278 				value = GetRandomFloat(0.0, 100.0);
   279 			}
   280 
   281 			if (IsClientObserver(i))
   282 			{			
   283 				specFound = true;
   284 				
   285 				if (value > highestSpecValue)
   286 				{
   287 					highestSpecValue = value;
   288 					highestSpecValueId = i;
   289 				}
   290 			}
   291 		}
   292 		
   293 		if (value >= highestValue)
   294 		{
   295 			highestValue = value;
   296 			highestValueId = i;
   297 		}
   298 	}
   299 	
   300 	if (specFound)
   301 	{
   302 		return highestSpecValueId;
   303 	}
   304 	
   305 	return highestValueId;
   306 }
sourcemod-central
Feed