dvander@1322: /**
ds@1330:  * vim: set ts=4 :
ds@1330:  * =============================================================================
ds@1330:  * SourceMod SQL Admins Plugin (Threaded)
ds@1330:  * Fetches admins from an SQL database dynamically.
dvander@1322:  *
ds@1330:  * SourceMod (C)2004-2007 AlliedModders LLC.  All rights reserved.
ds@1330:  * =============================================================================
dvander@1322:  *
ds@1330:  * This program is free software; you can redistribute it and/or modify it under
ds@1330:  * the terms of the GNU General Public License, version 3.0, as published by the
ds@1330:  * Free Software Foundation.
ds@1330:  * 
ds@1330:  * This program is distributed in the hope that it will be useful, but WITHOUT
ds@1330:  * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
ds@1330:  * FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
ds@1330:  * details.
dvander@1322:  *
ds@1330:  * You should have received a copy of the GNU General Public License along with
ds@1330:  * this program.  If not, see <http://www.gnu.org/licenses/>.
ds@1330:  *
ds@1330:  * As a special exception, AlliedModders LLC gives you permission to link the
ds@1330:  * code of this program (as well as its derivative works) to "Half-Life 2," the
ds@1330:  * "Source Engine," the "SourcePawn JIT," and any Game MODs that run on software
ds@1330:  * by the Valve Corporation.  You must obey the GNU General Public License in
ds@1330:  * all respects for all other code used.  Additionally, AlliedModders LLC grants
ds@1330:  * this exception to all derivative works.  AlliedModders LLC defines further
ds@1330:  * exceptions, found in LICENSE.txt (as of this writing, version JULY-31-2007),
ds@1330:  * or <http://www.sourcemod.net/license.php>.
dvander@1322:  *
dvander@1322:  * Version: $Id$
dvander@1322:  */
dvander@1322: 
dvander@1322: /* We like semicolons */
dvander@1322: #pragma semicolon 1
dvander@1322: 
dvander@1322: #include <sourcemod>
dvander@1322: 
dvander@1322: public Plugin:myinfo = 
dvander@1322: {
dvander@1322: 	name = "SQL Admins (Threaded)",
dvander@1322: 	author = "AlliedModders LLC",
dvander@1322: 	description = "Reads admins from SQL dynamically",
dvander@1322: 	version = SOURCEMOD_VERSION,
dvander@1322: 	url = "http://www.sourcemod.net/"
dvander@1322: };
dvander@1322: 
dvander@1322: /**
dvander@1322:  * Notes:
dvander@1322:  *
dvander@1322:  * 1) All queries in here are high priority.  This is because the admin stuff 
dvander@1322:  *    is very important.  Do not take this to mean that in your script, 
dvander@1322:  *    everything should be high priority.  
dvander@1322:  *
dvander@1322:  * 2) All callbacks are locked with "sequence numbers."  This is to make sure 
dvander@1322:  *    that multiple calls to sm_reloadadmins and the like do not make us 
dvander@1322:  *    store the results from two or more callbacks accidentally.  Instead, we 
dvander@1322:  *    check the sequence number in each callback with the current "allowed" 
dvander@1322:  *    sequence number, and if it doesn't match, the callback is cancelled.
dvander@1322:  *
dvander@1322:  * 3) Sequence numbers for groups and overrides are not cleared unless there 
dvander@1322:  *    was a 100% success in the fetch.  This is so we can potentially implement 
dvander@1322:  *    connection retries in the future.
dvander@1322:  *
dvander@1326:  * 4) Sequence numbers for the user cache are ignored except for being 
dvander@1326:  *    non-zero, which means players in-game should be re-checked for admin 
dvander@1322:  *    powers.
dvander@1322:  */
dvander@1322: 
dvander@1322: new Handle:hDatabase = INVALID_HANDLE;			/** Database connection */
dvander@1322: new g_sequence = 0;								/** Global unique sequence number */
dvander@1322: new ConnectLock = 0;							/** Connect sequence number */
dvander@1322: new RebuildCachePart[3] = {0};					/** Cache part sequence numbers */
dvander@1322: new PlayerSeq[MAXPLAYERS+1];					/** Player-specific sequence numbers */
dvander@1322: new bool:PlayerAuth[MAXPLAYERS+1];				/** Whether a player has been "pre-authed" */
dvander@1322: 
dvander@1322: #define _DEBUG
dvander@1322: 
dvander@1322: public OnMapEnd()
dvander@1322: {
dvander@1322: 	/**
dvander@1322: 	 * Clean up on map end just so we can start a fresh connection when we need it later.
dvander@1322: 	 */
dvander@1322: 	if (hDatabase != INVALID_HANDLE)
dvander@1322: 	{
dvander@1322: 		CloseHandle(hDatabase);
dvander@1322: 		hDatabase = INVALID_HANDLE;
dvander@1322: 	}
dvander@1322: }
dvander@1322: 
dvander@1322: public bool:OnClientConnect(client, String:rejectmsg[], maxlen)
dvander@1322: {
dvander@1322: 	PlayerSeq[client] = 0;
dvander@1322: 	PlayerAuth[client] = false;
dvander@1322: 	return true;
dvander@1322: }
dvander@1322: 
dvander@1322: public OnClientDisconnect(client)
dvander@1322: {
dvander@1322: 	PlayerSeq[client] = 0;
dvander@1322: 	PlayerAuth[client] = false;
dvander@1322: }
dvander@1322: 
dvander@1322: public OnDatabaseConnect(Handle:owner, Handle:hndl, const String:error[], any:data)
dvander@1322: {
dvander@1322: #if defined _DEBUG
dvander@1322: 	PrintToServer("OnDatabaseConnect(%x,%x,%d) ConnectLock=%d", owner, hndl, data, ConnectLock);
dvander@1322: #endif
dvander@1322: 
dvander@1322: 	/**
dvander@1322: 	 * If this happens to be an old connection request, ignore it.
dvander@1322: 	 */
dvander@1322: 	if (data != ConnectLock || hDatabase != INVALID_HANDLE)
dvander@1322: 	{
dvander@1322: 		if (hndl != INVALID_HANDLE)
dvander@1322: 		{
dvander@1322: 			CloseHandle(hndl);
dvander@1322: 		}
dvander@1322: 		return;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	ConnectLock = 0;
dvander@1322: 	hDatabase = hndl;
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * See if the connection is valid.  If not, don't un-mark the caches
dvander@1322: 	 * as needing rebuilding, in case the next connection request works.
dvander@1322: 	 */
dvander@1322: 	if (hDatabase == INVALID_HANDLE)
dvander@1322: 	{
dvander@1322: 		LogError("Failed to connect to database: %s", error);
dvander@1322: 		return;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * See if we need to get any of the cache stuff now.
dvander@1322: 	 */
dvander@1322: 	new sequence;
dvander@1322: 	if ((sequence = RebuildCachePart[_:AdminCache_Overrides]) != 0)
dvander@1322: 	{
dvander@1322: 		FetchOverrides(hDatabase, sequence);
dvander@1322: 	}
dvander@1322: 	if ((sequence = RebuildCachePart[_:AdminCache_Groups]) != 0)
dvander@1322: 	{
dvander@1322: 		FetchGroups(hDatabase, sequence);
dvander@1322: 	}
dvander@1322: 	if ((sequence = RebuildCachePart[_:AdminCache_Admins]) != 0)
dvander@1322: 	{
dvander@1322: 		FetchUsersWeCan(hDatabase);
dvander@1322: 	}
dvander@1322: }
dvander@1322: 
dvander@1322: RequestDatabaseConnection()
dvander@1322: {
dvander@1322: 	ConnectLock = ++g_sequence;
dvander@1324: 	if (SQL_CheckConfig("admins"))
dvander@1324: 	{
dvander@1324: 		SQL_TConnect(OnDatabaseConnect, "admins", ConnectLock);
dvander@1324: 	} else {
dvander@1324: 		SQL_TConnect(OnDatabaseConnect, "default", ConnectLock);
dvander@1324: 	}
dvander@1322: }
dvander@1322: 
dvander@1322: public OnRebuildAdminCache(AdminCachePart:part)
dvander@1322: {
dvander@1322: 	/**
dvander@1322: 	 * Mark this part of the cache as being rebuilt.  This is used by the 
dvander@1322: 	 * callback system to determine whether the results should still be 
dvander@1322: 	 * used.
dvander@1322: 	 */
dvander@1322: 	new sequence = ++g_sequence;
dvander@1322: 	RebuildCachePart[_:part] = sequence;
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * If we don't have a database connection, we can't do any lookups just yet.
dvander@1322: 	 */
dvander@1322: 	if (!hDatabase)
dvander@1322: 	{
dvander@1322: 		/**
dvander@1322: 		 * Ask for a new connection if we need it.
dvander@1322: 		 */
dvander@1322: 		if (!ConnectLock)
dvander@1322: 		{
dvander@1322: 			RequestDatabaseConnection();
dvander@1322: 		}
dvander@1322: 		return;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	if (part == AdminCache_Overrides)
dvander@1322: 	{
dvander@1322: 		FetchOverrides(hDatabase, sequence);
dvander@1322: 	} else if (part == AdminCache_Groups) {
dvander@1322: 		FetchGroups(hDatabase, sequence);
dvander@1322: 	} else if (part == AdminCache_Admins) {
dvander@1322: 		FetchUsersWeCan(hDatabase);
dvander@1322: 	}
dvander@1322: }
dvander@1322: 
dvander@1322: public Action:OnClientPreAdminCheck(client)
dvander@1322: {
dvander@1322: 	PlayerAuth[client] = true;
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * Play nice with other plugins.  If there's no database, don't delay the 
dvander@1322: 	 * connection process.  Unfortunately, we can't attempt anything else and 
dvander@1322: 	 * we just have to hope either the database is waiting or someone will type 
dvander@1322: 	 * sm_reloadadmins.
dvander@1322: 	 */
dvander@1322: 	if (hDatabase == INVALID_HANDLE)
dvander@1322: 	{
dvander@1322: 		return Plugin_Continue;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * Similarly, if the cache is in the process of being rebuilt, don't delay 
dvander@1322: 	 * the user's normal connection flow.  The database will soon auth the user 
dvander@1322: 	 * normally.
dvander@1322: 	 */
dvander@1322: 	if (RebuildCachePart[_:AdminCache_Admins] != 0)
dvander@1322: 	{
dvander@1322: 		return Plugin_Continue;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * If someone has already assigned an admin ID (bad bad bad), don't 
dvander@1322: 	 * bother waiting.
dvander@1322: 	 */
dvander@1322: 	if (GetUserAdmin(client) != INVALID_ADMIN_ID)
dvander@1322: 	{
dvander@1322: 		return Plugin_Continue;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	FetchUser(hDatabase, client);
dvander@1322: 	
dvander@1322: 	return Plugin_Handled;
dvander@1322: }
dvander@1322: 
dvander@1322: public OnReceiveUserGroups(Handle:owner, Handle:hndl, const String:error[], any:data)
dvander@1322: {
dvander@1322: 	new Handle:pk = Handle:data;
dvander@1322: 	ResetPack(pk);
dvander@1322: 	
dvander@1322: 	new client = ReadPackCell(pk);
dvander@1322: 	new sequence = ReadPackCell(pk);
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * Make sure it's the same client.
dvander@1322: 	 */
dvander@1322: 	if (PlayerSeq[client] != sequence)
dvander@1322: 	{
dvander@1322: 		CloseHandle(pk);
dvander@1322: 		return;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	new AdminId:adm = AdminId:ReadPackCell(pk);
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * Someone could have sneakily changed the admin id while we waited.
dvander@1322: 	 */
dvander@1322: 	if (GetUserAdmin(client) != adm)
dvander@1322: 	{
dvander@1322: 		NotifyPostAdminCheck(client);
dvander@1322: 		CloseHandle(pk);
dvander@1322: 		return;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * See if we got results.
dvander@1322: 	 */
dvander@1322: 	if (hndl == INVALID_HANDLE)
dvander@1322: 	{
dvander@1322: 		decl String:query[255];
dvander@1322: 		ReadPackString(pk, query, sizeof(query));
dvander@1322: 		LogError("SQL error receiving user: %s", error);
dvander@1322: 		LogError("Query dump: %s", query);
dvander@1322: 		NotifyPostAdminCheck(client);
dvander@1322: 		CloseHandle(pk);
dvander@1322: 		return;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	decl String:name[80];
dvander@1322: 	new GroupId:gid;
dvander@1322: 	
dvander@1322: 	while (SQL_FetchRow(hndl))
dvander@1322: 	{
dvander@1322: 		SQL_FetchString(hndl, 0, name, sizeof(name));
dvander@1322: 		
dvander@1322: 		if ((gid = FindAdmGroup(name)) == INVALID_GROUP_ID)
dvander@1322: 		{
dvander@1322: 			continue;
dvander@1322: 		}
dvander@1322: 		
dvander@1322: #if defined _DEBUG
dvander@1322: 		PrintToServer("Binding user group (%d, %d, %d, %s, %d)", client, sequence, adm, name, gid);
dvander@1322: #endif
dvander@1322: 		
dvander@1322: 		AdminInheritGroup(adm, gid);
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * We're DONE! Omg.
dvander@1322: 	 */
dvander@1322: 	NotifyPostAdminCheck(client);
dvander@1322: 	CloseHandle(pk);
dvander@1322: }
dvander@1322: 
dvander@1322: public OnReceiveUser(Handle:owner, Handle:hndl, const String:error[], any:data)
dvander@1322: {
dvander@1322: 	new Handle:pk = Handle:data;
dvander@1322: 	ResetPack(pk);
dvander@1322: 	
dvander@1322: 	new client = ReadPackCell(pk);
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * Check if this is the latest result request.
dvander@1322: 	 */
dvander@1322: 	new sequence = ReadPackCell(pk);
dvander@1322: 	if (PlayerSeq[client] != sequence)
dvander@1322: 	{
dvander@1322: 		/* Discard everything, since we're out of sequence. */
dvander@1322: 		CloseHandle(pk);
dvander@1322: 		return;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * If we need to use the results, make sure they succeeded.
dvander@1322: 	 */
dvander@1322: 	if (hndl == INVALID_HANDLE)
dvander@1322: 	{
dvander@1322: 		decl String:query[255];
dvander@1322: 		ReadPackString(pk, query, sizeof(query));
dvander@1322: 		LogError("SQL error receiving user: %s", error);
dvander@1322: 		LogError("Query dump: %s", query);
dvander@1322: 		RunAdminCacheChecks(client);
dvander@1322: 		NotifyPostAdminCheck(client);
dvander@1322: 		CloseHandle(pk);
dvander@1322: 		return;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	new num_accounts = SQL_GetRowCount(hndl);
dvander@1322: 	if (num_accounts == 0)
dvander@1322: 	{
dvander@1322: 		RunAdminCacheChecks(client);
dvander@1322: 		NotifyPostAdminCheck(client);
dvander@1322: 		CloseHandle(pk);
dvander@1322: 		return;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	decl String:authtype[16];
dvander@1322: 	decl String:identity[80];
dvander@1322: 	decl String:password[80];
dvander@1322: 	decl String:flags[32];
dvander@1322: 	decl String:name[80];
dvander@1322: 	new AdminId:adm, id;
dvander@1403: 	new immunity;
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * Cache user info -- [0] = db id, [1] = cache id, [2] = groups
dvander@1322: 	 */
dvander@1322: 	decl user_lookup[num_accounts][3];
dvander@1322: 	new total_users = 0;
dvander@1322: 	
dvander@1322: 	while (SQL_FetchRow(hndl))
dvander@1322: 	{
dvander@1322: 		id = SQL_FetchInt(hndl, 0);
dvander@1322: 		SQL_FetchString(hndl, 1, authtype, sizeof(authtype));
dvander@1322: 		SQL_FetchString(hndl, 2, identity, sizeof(identity));
dvander@1322: 		SQL_FetchString(hndl, 3, password, sizeof(password));
dvander@1322: 		SQL_FetchString(hndl, 4, flags, sizeof(flags));
dvander@1322: 		SQL_FetchString(hndl, 5, name, sizeof(name));
dvander@1403: 		immunity = SQL_FetchInt(hndl, 7);
dvander@1322: 		
dvander@1322: 		/* For dynamic admins we clear anything already in the cache. */
dvander@1322: 		if ((adm = FindAdminByIdentity(authtype, identity)) != INVALID_ADMIN_ID)
dvander@1322: 		{
dvander@1322: 			RemoveAdmin(adm);
dvander@1322: 		}
dvander@1322: 		
dvander@1322: 		adm = CreateAdmin(name);
dvander@1322: 		if (!BindAdminIdentity(adm, authtype, identity))
dvander@1322: 		{
dvander@1322: 			LogError("Could not bind prefetched SQL admin (authtype \"%s\") (identity \"%s\")", authtype, identity);
dvander@1322: 			continue;
dvander@1322: 		}
dvander@1322: 		
dvander@1322: 		user_lookup[total_users][0] = id;
dvander@1322: 		user_lookup[total_users][1] = _:adm;
dvander@1322: 		user_lookup[total_users][2] = SQL_FetchInt(hndl, 6);
dvander@1322: 		total_users++;
dvander@1322: 		
dvander@1322: #if defined _DEBUG
dvander@1403: 		PrintToServer("Found SQL admin (%d,%s,%s,%s,%s,%s,%d):%d:%d", id, authtype, identity, password, flags, name, immunity, adm, user_lookup[total_users-1][2]);
dvander@1322: #endif
dvander@1322: 		
dvander@1322: 		/* See if this admin wants a password */
dvander@1322: 		if (password[0] != '\0')
dvander@1322: 		{
dvander@1322: 			SetAdminPassword(adm, password);
dvander@1322: 		}
dvander@1403: 
dvander@1403: 		SetAdminImmunityLevel(adm, immunity);
dvander@1322: 		
dvander@1322: 		/* Apply each flag */
dvander@1322: 		new len = strlen(flags);
dvander@1322: 		new AdminFlag:flag;
dvander@1322: 		for (new i=0; i<len; i++)
dvander@1322: 		{
dvander@1322: 			if (!FindFlagByChar(flags[i], flag))
dvander@1322: 			{
dvander@1322: 				continue;
dvander@1322: 			}
dvander@1322: 			SetAdminFlag(adm, flag, true);
dvander@1322: 		}
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * Try binding the user.
dvander@1322: 	 */	
dvander@1322: 	new group_count = 0;
dvander@1322: 	RunAdminCacheChecks(client);
dvander@1322: 	adm = GetUserAdmin(client);
dvander@1322: 	id = 0;
dvander@1322: 	
dvander@1322: 	
dvander@1322: 	for (new i=0; i<total_users; i++)
dvander@1322: 	{
dvander@1322: 		if (user_lookup[i][1] == _:adm)
dvander@1322: 		{
dvander@1322: 			id = user_lookup[i][0];
dvander@1322: 			group_count = user_lookup[i][2];
dvander@1322: 			break;
dvander@1322: 		}
dvander@1322: 	}
dvander@1322: 	
dvander@1322: #if defined _DEBUG
dvander@1322: 	PrintToServer("Binding client (%d, %d) resulted in: (%d, %d, %d)", client, sequence, id, adm, group_count);
dvander@1322: #endif
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * If we can't verify that we assigned a database admin, or the user has no 
dvander@1322: 	 * groups, don't bother doing anything.
dvander@1322: 	 */
dvander@1322: 	if (!id || !group_count)
dvander@1322: 	{
dvander@1322: 		NotifyPostAdminCheck(client);
dvander@1322: 		CloseHandle(pk);
dvander@1322: 		return;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * The user has groups -- we need to fetch them!
dvander@1322: 	 */
dvander@1322: 	decl String:query[255];
dvander@1322: 	Format(query, sizeof(query), "SELECT g.name FROM sm_admins_groups ag JOIN sm_groups g ON ag.group_id = g.id WHERE ag.admin_id = %d", id);
dvander@1322: 	 
dvander@1322: 	ResetPack(pk);
dvander@1322: 	WritePackCell(pk, client);
dvander@1322: 	WritePackCell(pk, sequence);
dvander@1322: 	WritePackCell(pk, _:adm);
dvander@1322: 	WritePackString(pk, query);
dvander@1322: 	
dvander@1322: 	SQL_TQuery(owner, OnReceiveUserGroups, query, pk, DBPrio_High);
dvander@1322: }
dvander@1322: 
dvander@1322: FetchUser(Handle:db, client)
dvander@1322: {
dvander@1322: 	decl String:name[65];
dvander@1322: 	decl String:safe_name[140];
dvander@1322: 	decl String:steamid[32];
dvander@1322: 	decl String:ipaddr[24];
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * Get authentication information from the client.
dvander@1322: 	 */
dvander@1322: 	GetClientName(client, name, sizeof(name));
dvander@1322: 	GetClientIP(client, ipaddr, sizeof(ipaddr));
dvander@1322: 	
dvander@1322: 	steamid[0] = '\0';
dvander@1322: 	if (GetClientAuthString(client, steamid, sizeof(steamid)))
dvander@1322: 	{
dvander@1322: 		if (StrEqual(steamid, "STEAM_ID_LAN"))
dvander@1322: 		{
dvander@1322: 			steamid[0] = '\0';
dvander@1322: 		}
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	SQL_QuoteString(db, name, safe_name, sizeof(safe_name));
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * Construct the query using the information the user gave us.
dvander@1322: 	 */
dvander@1322: 	decl String:query[512];
dvander@1322: 	new len = 0;
dvander@1322: 	
dvander@1403: 	len += Format(query[len], sizeof(query)-len, "SELECT a.id, a.authtype, a.identity, a.password, a.flags, a.name, COUNT(ag.group_id), immunity");
dvander@1322: 	len += Format(query[len], sizeof(query)-len, " FROM sm_admins a LEFT JOIN sm_admins_groups ag ON a.id = ag.admin_id WHERE ");
dvander@1322: 	len += Format(query[len], sizeof(query)-len, " (a.authtype = 'ip' AND a.identity = '%s')", ipaddr);
dvander@1322: 	len += Format(query[len], sizeof(query)-len, " OR (a.authtype = 'name' AND a.identity = '%s')", safe_name);
dvander@1322: 	if (steamid[0] != '\0')
dvander@1322: 	{
dvander@1322: 		len += Format(query[len], sizeof(query)-len, " OR (a.authtype = 'steam' AND a.identity = '%s')", steamid);
dvander@1322: 	}
dvander@1322: 	len += Format(query[len], sizeof(query)-len, " GROUP BY a.id");
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * Send the actual query.
dvander@1322: 	 */	
dvander@1322: 	PlayerSeq[client] = ++g_sequence;
dvander@1322: 	
dvander@1322: 	new Handle:pk;
dvander@1322: 	pk = CreateDataPack();
dvander@1322: 	WritePackCell(pk, client);
dvander@1322: 	WritePackCell(pk, PlayerSeq[client]);
dvander@1322: 	WritePackString(pk, query);
dvander@1322: 	
dvander@1322: #if defined _DEBUG
dvander@1322: 	PrintToServer("Sending user query: %s", query);
dvander@1322: #endif
dvander@1322: 	
dvander@1322: 	SQL_TQuery(db, OnReceiveUser, query, pk, DBPrio_High);
dvander@1322: }
dvander@1322: 
dvander@1322: FetchUsersWeCan(Handle:db)
dvander@1322: {
dvander@1322: 	new max_clients = GetMaxClients();
dvander@1322: 	
dvander@1322: 	for (new i=1; i<=max_clients; i++)
dvander@1322: 	{
dvander@1322: 		if (PlayerAuth[i] && GetUserAdmin(i) == INVALID_ADMIN_ID)
dvander@1322: 		{
dvander@1322: 			FetchUser(db, i);
dvander@1322: 		}
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * This round of updates is done.  Go in peace.
dvander@1322: 	 */
dvander@1322: 	RebuildCachePart[_:AdminCache_Admins] = 0;
dvander@1322: }
dvander@1322: 
dvander@1326: 
dvander@1326: public OnReceiveGroupImmunity(Handle:owner, Handle:hndl, const String:error[], any:data)
dvander@1326: {
dvander@1326: 	new Handle:pk = Handle:data;
dvander@1326: 	ResetPack(pk);
dvander@1326: 	
dvander@1326: 	/**
dvander@1326: 	 * Check if this is the latest result request.
dvander@1326: 	 */
dvander@1326: 	new sequence = ReadPackCell(pk);
dvander@1326: 	if (RebuildCachePart[_:AdminCache_Groups] != sequence)
dvander@1326: 	{
dvander@1326: 		/* Discard everything, since we're out of sequence. */
dvander@1326: 		CloseHandle(pk);
dvander@1326: 		return;
dvander@1326: 	}
dvander@1326: 	
dvander@1326: 	/**
dvander@1326: 	 * If we need to use the results, make sure they succeeded.
dvander@1326: 	 */
dvander@1326: 	if (hndl == INVALID_HANDLE)
dvander@1326: 	{
dvander@1326: 		decl String:query[255];
dvander@1326: 		ReadPackString(pk, query, sizeof(query));		
dvander@1326: 		LogError("SQL error receiving group immunity: %s", error);
dvander@1326: 		LogError("Query dump: %s", query);
dvander@1326: 		CloseHandle(pk);	
dvander@1326: 		return;
dvander@1326: 	}
dvander@1326: 	
dvander@1326: 	/* We're done with the pack forever. */
dvander@1326: 	CloseHandle(pk);
dvander@1326: 	
dvander@1326: 	while (SQL_FetchRow(hndl))
dvander@1326: 	{
dvander@1326: 		decl String:group1[80];
dvander@1326: 		decl String:group2[80];
dvander@1326: 		new GroupId:gid1, GroupId:gid2;
dvander@1326: 		
dvander@1326: 		SQL_FetchString(hndl, 0, group1, sizeof(group1));
dvander@1326: 		SQL_FetchString(hndl, 1, group2, sizeof(group2));
dvander@1326: 		
dvander@1326: 		if (((gid1 = FindAdmGroup(group1)) == INVALID_GROUP_ID)
dvander@1326: 			|| (gid2 = FindAdmGroup(group2)) == INVALID_GROUP_ID)
dvander@1326: 		{
dvander@1326: 			continue;
dvander@1326: 		}
dvander@1326: 		
dvander@1326: 		SetAdmGroupImmuneFrom(gid1, gid2);
dvander@1326: #if defined _DEBUG
dvander@1326: 		PrintToServer("SetAdmGroupImmuneFrom(%d, %d)", gid1, gid2);
dvander@1326: #endif
dvander@1326: 	}
dvander@1326: 	
dvander@1326: 	/* Clear the sequence so another connect doesn't refetch */
dvander@1326: 	RebuildCachePart[_:AdminCache_Groups] = 0;
dvander@1326: }
dvander@1326: 
dvander@1322: public OnReceiveGroupOverrides(Handle:owner, Handle:hndl, const String:error[], any:data)
dvander@1322: {
dvander@1322: 	new Handle:pk = Handle:data;
dvander@1322: 	ResetPack(pk);
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * Check if this is the latest result request.
dvander@1322: 	 */
dvander@1322: 	new sequence = ReadPackCell(pk);
dvander@1322: 	if (RebuildCachePart[_:AdminCache_Groups] != sequence)
dvander@1322: 	{
dvander@1322: 		/* Discard everything, since we're out of sequence. */
dvander@1322: 		CloseHandle(pk);
dvander@1322: 		return;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * If we need to use the results, make sure they succeeded.
dvander@1322: 	 */
dvander@1322: 	if (hndl == INVALID_HANDLE)
dvander@1322: 	{
dvander@1322: 		decl String:query[255];
dvander@1322: 		ReadPackString(pk, query, sizeof(query));		
dvander@1322: 		LogError("SQL error receiving group overrides: %s", error);
dvander@1322: 		LogError("Query dump: %s", query);
dvander@1322: 		CloseHandle(pk);	
dvander@1322: 		return;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * Fetch the overrides.
dvander@1322: 	 */
dvander@1322: 	decl String:name[80];
dvander@1322: 	decl String:type[16];
dvander@1322: 	decl String:command[64];
dvander@1322: 	decl String:access[16];
dvander@1322: 	new GroupId:gid;
dvander@1322: 	while (SQL_FetchRow(hndl))
dvander@1322: 	{
dvander@1322: 		SQL_FetchString(hndl, 0, name, sizeof(name));
dvander@1322: 		SQL_FetchString(hndl, 1, type, sizeof(type));
dvander@1322: 		SQL_FetchString(hndl, 2, command, sizeof(command));
dvander@1322: 		SQL_FetchString(hndl, 3, access, sizeof(access));
dvander@1322: 		
dvander@1322: 		/* Find the group.  This is actually faster than doing the ID lookup. */
dvander@1322: 		if ((gid = FindAdmGroup(name)) == INVALID_GROUP_ID)
dvander@1322: 		{
dvander@1322: 			/* Oh well, just ignore it. */
dvander@1322: 			continue;
dvander@1322: 		}
dvander@1322: 		
dvander@1322: 		new OverrideType:o_type = Override_Command;
dvander@1322: 		if (StrEqual(type, "group"))
dvander@1322: 		{
dvander@1322: 			o_type = Override_CommandGroup;
dvander@1322: 		}
dvander@1322: 				
dvander@1322: 		new OverrideRule:o_rule = Command_Deny;
dvander@1322: 		if (StrEqual(access, "allow"))
dvander@1322: 		{
dvander@1322: 			o_rule = Command_Allow;
dvander@1322: 		}
dvander@1322: 				
dvander@1322: #if defined _DEBUG
dvander@1322: 		PrintToServer("AddAdmGroupCmdOverride(%d, %s, %d, %d)", gid, command, o_type, o_rule);
dvander@1322: #endif
dvander@1322: 				
dvander@1322: 		AddAdmGroupCmdOverride(gid, command, o_type, o_rule);
dvander@1322: 	}
dvander@1322: 	
dvander@1326: 	/**
dvander@1326: 	 * It's time to get the group immunity list.
dvander@1326: 	 */
dvander@1326: 	new len = 0;
dvander@1326: 	decl String:query[256];
dvander@1326: 	len += Format(query[len], sizeof(query)-len, "SELECT g1.name, g2.name FROM sm_group_immunity gi");
dvander@1326: 	len += Format(query[len], sizeof(query)-len, " LEFT JOIN sm_groups g1 ON g1.id = gi.group_id ");
dvander@1326: 	len += Format(query[len], sizeof(query)-len, " LEFT JOIN sm_groups g2 ON g2.id = gi.other_id");
dvander@1326: 
dvander@1326: 	ResetPack(pk);
dvander@1326: 	WritePackCell(pk, sequence);
dvander@1326: 	WritePackString(pk, query);
dvander@1326: 	
dvander@1326: 	SQL_TQuery(owner, OnReceiveGroupImmunity, query, pk, DBPrio_High);
dvander@1322: }
dvander@1322: 
dvander@1322: public OnReceiveGroups(Handle:owner, Handle:hndl, const String:error[], any:data)
dvander@1322: {
dvander@1322: 	new Handle:pk = Handle:data;
dvander@1322: 	ResetPack(pk);
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * Check if this is the latest result request.
dvander@1322: 	 */
dvander@1322: 	new sequence = ReadPackCell(pk);
dvander@1322: 	if (RebuildCachePart[_:AdminCache_Groups] != sequence)
dvander@1322: 	{
dvander@1322: 		/* Discard everything, since we're out of sequence. */
dvander@1322: 		CloseHandle(pk);
dvander@1322: 		return;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * If we need to use the results, make sure they succeeded.
dvander@1322: 	 */
dvander@1322: 	if (hndl == INVALID_HANDLE)
dvander@1322: 	{
dvander@1322: 		decl String:query[255];
dvander@1322: 		ReadPackString(pk, query, sizeof(query));
dvander@1322: 		LogError("SQL error receiving groups: %s", error);
dvander@1322: 		LogError("Query dump: %s", query);
dvander@1322: 		CloseHandle(pk);
dvander@1322: 		return;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * Now start fetching groups.
dvander@1322: 	 */
dvander@1322: 	decl String:flags[32];
dvander@1322: 	decl String:name[128];
dvander@1403: 	new immunity;
dvander@1322: 	while (SQL_FetchRow(hndl))
dvander@1322: 	{
dvander@1403: 		SQL_FetchString(hndl, 0, flags, sizeof(flags));
dvander@1403: 		SQL_FetchString(hndl, 1, name, sizeof(name));
dvander@1403: 		immunity = SQL_FetchInt(hndl, 2);
dvander@1322: 		
dvander@1322: #if defined _DEBUG
dvander@1403: 		PrintToServer("Adding group (%d, %s, %s)", immunity, flags, name);
dvander@1322: #endif
dvander@1322: 		
dvander@1322: 		/* Find or create the group */
dvander@1322: 		new GroupId:gid;
dvander@1322: 		if ((gid = FindAdmGroup(name)) == INVALID_GROUP_ID)
dvander@1322: 		{
dvander@1322: 			gid = CreateAdmGroup(name);
dvander@1322: 		}
dvander@1403: 
dvander@1322: 		/* Add flags from the database to the group */
dvander@1322: 		new num_flag_chars = strlen(flags);
dvander@1322: 		for (new i=0; i<num_flag_chars; i++)
dvander@1322: 		{
dvander@1322: 			decl AdminFlag:flag;
dvander@1322: 			if (!FindFlagByChar(flags[i], flag))
dvander@1322: 			{
dvander@1322: 				continue;
dvander@1322: 			}
dvander@1322: 			SetAdmGroupAddFlag(gid, flag, true);
dvander@1322: 		}
dvander@1322: 		
dvander@1403: 		SetAdmGroupImmunityLevel(gid, immunity);
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	/**
dvander@1326: 	 * It's time to get the group override list.
dvander@1322: 	 */
dvander@1322: 	decl String:query[255];
dvander@1322: 	Format(query, 
dvander@1322: 		sizeof(query), 
dvander@1322: 		"SELECT g.name, og.type, og.name, og.access FROM sm_group_overrides og JOIN sm_groups g ON og.group_id = g.id ORDER BY g.id DESC");
dvander@1322: 
dvander@1322: 	ResetPack(pk);
dvander@1322: 	WritePackCell(pk, sequence);
dvander@1322: 	WritePackString(pk, query);
dvander@1322: 	
dvander@1322: 	SQL_TQuery(owner, OnReceiveGroupOverrides, query, pk, DBPrio_High);
dvander@1322: }
dvander@1322: 
dvander@1322: FetchGroups(Handle:db, sequence)
dvander@1322: {
dvander@1322: 	decl String:query[255];
dvander@1322: 	new Handle:pk;
dvander@1322: 	
dvander@1403: 	Format(query, sizeof(query), "SELECT flags, name, immunity_level FROM sm_groups");
dvander@1322: 
dvander@1322: 	pk = CreateDataPack();
dvander@1322: 	WritePackCell(pk, sequence);
dvander@1322: 	WritePackString(pk, query);
dvander@1322: 	
dvander@1322: 	SQL_TQuery(db, OnReceiveGroups, query, pk, DBPrio_High);
dvander@1322: }
dvander@1322: 
dvander@1322: public OnReceiveOverrides(Handle:owner, Handle:hndl, const String:error[], any:data)
dvander@1322: {
dvander@1322: 	new Handle:pk = Handle:data;
dvander@1322: 	ResetPack(pk);
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * Check if this is the latest result request.
dvander@1322: 	 */
dvander@1322: 	new sequence = ReadPackCell(pk);
dvander@1322: 	if (RebuildCachePart[_:AdminCache_Overrides] != sequence)
dvander@1322: 	{
dvander@1322: 		/* Discard everything, since we're out of sequence. */
dvander@1322: 		CloseHandle(pk);
dvander@1322: 		return;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * If we need to use the results, make sure they succeeded.
dvander@1322: 	 */
dvander@1322: 	if (hndl == INVALID_HANDLE)
dvander@1322: 	{
dvander@1322: 		decl String:query[255];
dvander@1322: 		ReadPackString(pk, query, sizeof(query));
dvander@1322: 		LogError("SQL error receiving overrides: %s", error);
dvander@1322: 		LogError("Query dump: %s", query);
dvander@1322: 		CloseHandle(pk);
dvander@1322: 		return;
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	/**
dvander@1322: 	 * We're done with you, now.
dvander@1322: 	 */
dvander@1322: 	CloseHandle(pk);
dvander@1322: 	
dvander@1322: 	decl String:type[64];
dvander@1322: 	decl String:name[64];
dvander@1322: 	decl String:flags[32];
dvander@1322: 	new flag_bits;
dvander@1322: 	while (SQL_FetchRow(hndl))
dvander@1322: 	{
dvander@1322: 		SQL_FetchString(hndl, 0, type, sizeof(type));
dvander@1322: 		SQL_FetchString(hndl, 1, name, sizeof(name));
dvander@1322: 		SQL_FetchString(hndl, 2, flags, sizeof(flags));
dvander@1322: 		
dvander@1322: #if defined _DEBUG
dvander@1322: 		PrintToServer("Adding override (%s, %s, %s)", type, name, flags);
dvander@1322: #endif
dvander@1322: 		
dvander@1322: 		flag_bits = ReadFlagString(flags);
dvander@1322: 		if (StrEqual(type, "command"))
dvander@1322: 		{
dvander@1322: 			AddCommandOverride(name, Override_Command, flag_bits);
dvander@1322: 		} else if (StrEqual(type, "group")) {
dvander@1322: 			AddCommandOverride(name, Override_CommandGroup, flag_bits);
dvander@1322: 		}
dvander@1322: 	}
dvander@1322: 	
dvander@1322: 	/* Clear the sequence so another connect doesn't refetch */
dvander@1322: 	RebuildCachePart[_:AdminCache_Overrides] = 0;
dvander@1322: }
dvander@1322: 
dvander@1322: FetchOverrides(Handle:db, sequence)
dvander@1322: {
dvander@1322: 	decl String:query[255];
dvander@1322: 	new Handle:pk;
dvander@1322: 	
dvander@1322: 	Format(query, sizeof(query), "SELECT type, name, flags FROM sm_overrides");
dvander@1322: 
dvander@1322: 	pk = CreateDataPack();
dvander@1322: 	WritePackCell(pk, sequence);
dvander@1322: 	WritePackString(pk, query);
dvander@1322: 	
dvander@1322: 	SQL_TQuery(db, OnReceiveOverrides, query, pk, DBPrio_High);
dvander@1322: }
dvander@1322: